The classification of volcanic rocks based on immobile elements (after Winchester & Floyd, 1977)


Gnuplot's Script

# Gnuplot script for plotting classification based
# on immobile element after Winchester & Floyd (1977)
# 22-01-2002 by IWW <warmada@altavista.net>
#

set term postscript enhanced 'Roman' 11
set output 'immobile.ps'

set size .5,.55
set border 3
set log xy
set xrange [0.01:100]
set yrange [0.002:2.85]
set xlabel '{/Roman=12 Nb/Y}'
set ylabel '{/Roman=12 Zr/Ti}' 1.25
set xtics nomirror
set ytics nomirror
set grid

# label --> classification
# ------------------------
set label 21 '{/Roman=11 comendite}' at .6,1.87 center
set label 22 '{/Roman=11 pantellerite}' at .6,1.27 center
set label 23 '{/Roman=11 phonolite}' at 4.75,.675 left
set label 24 '{/Roman=11 rhyolite}' at .525,.2 right
set label 25 '{/Roman=11 trachyte}' at 2.1,.1 left
set label 26 '{/Roman=11 rhyodacite}' at .2,.08 center
set label 27 '{/Roman=11 dacite}' at .2,.055 center
set label 28 '{/Roman=11 trachy-}' at 1.55,.05 center
set label 29 '{/Roman=11 andesite}' at 1.55,.035 center
set label 30 '{/Roman=11 andesite}' at .2,.0225 right
set label 31 '{/Roman=11 andesite/basalt}' at .2,.0085 right
set label 32 '{/Roman=11 alkali-}' at .85,.01 left
set label 33 '{/Roman=11 basalt}' at .85,.007 left
set label 34 '{/Roman=11 basanite}' at 3.85,.015 left
set label 35 '{/Roman=11 nephelinite}' at 3.85,.0105 left
set label 36 '{/Roman=11 sub-alkaline}' at .125,.00425 center
set label 37 '{/Roman=11 basalt}' at .125,0.003 center

plot 'Winchester.cls' index 0 notitle with lines 1, \
     '' index 1 notitle with lines 2, \
     '' index 2 using 1:2 smooth bezier notitle with lines 1, \
     '' index 3 using 1:2 smooth bezier notitle with lines 2

#pause -1


This document was generated on January, 22 2002 using texi2html