The classification of volcanic rocks according to their cation percentages of Al, (Fe_[total] + Ti) and Mg

set term postscript enhanced monochrome 'Roman' 8
set output 'cation.ps'
set size square 0.535,0.65
set angle degrees
set noborder
set xrange [-10:100]
set yrange [-10:100]
set noxtics
set noytics
set key 100,90

# plot triangular coordinate system

#gx(x,y) = x + y * cos(60)
gx(x,y) = 100 - (x + y) + y * cos(60)
gy(x,y) = y * cos(30)

set label 41 'Al' at -2.5,-3.5 center font 'Times,12'
set label 42 'Fe_{tot} + Ti' at 50,90.5 center font 'Times,12'
set label 43 'Mg' at 102.5,-3.5 center font 'Times,12'

set label 44 'High-Fe' at 39,41 center
set label 45 'tholeiite' at 39,38 center
set label 46 'basalt' at 39,35 center

set label 47 'High-Mg' at 49,21 right
set label 48 'tholeiite' at 49,18 right
set label 49 'basalt' at 49,15 right

# rotate command in set label will rotate text into 90, because until
# the recent version of gnuplot (3.8x) haven't setting with arbitrary
# rotation angle. To adjust it on the right angle, please try to edit
# the postscript output ot this script...
#
# Click here to see how to edit the postscript output of this script

set label 50 'THOLEIITE' at 20,35 rotate
set label 51 'CALC-ALKALINE' at 15,10 rotate
set label 52 'KOMATIITE' at 70,30 rotate

set label 53 'Komatiitic' at 60,40 rotate
set label 54 'basalt' at 55,40 rotate

set label 55 'Komatiite' at 75,20 rotate

set label 56 'Andesite' at 20,35 rotate

set label 57 'Dacite' at 15,30 rotate

set label 58 'Rhyolite' at 10,15 rotate

set label 59 'Rhyolite' at 8,5 rotate

set label 60 'Dacite' at 18,10 rotate

set label 61 'Andesite' at 24,12 rotate

set label 62 'Basalt' at 32,20 rotate

plot 'cation.dat' index 5 using (gx($1,$2)):(gy($1,$2)) notitle with lines 2, \
    " index 6 using (gx($1,$2)):(gy($1,$2)) smooth bezier notitle with lines 2, \
    " index 1 using (gx($1,$2)):(gy($1,$2)) notitle with lines 1, \
    " index 1 using (gx($1,$2)):(gy($1,$2)) notitle with points 7, \
    " index 2 using (gx($1,$2)):(gy($1,$2)):(100) smooth acsplines notitle with lines 1, \
    " index 2 using (gx($1,$2)):(gy($1,$2)) notitle with points 7, \
    " index 3 using (gx($1,$2)):(gy($1,$2)) notitle with lines 1, \
    " index 3 using (gx($1,$2)):(gy($1,$2)) notitle with points 7, \
    " index 4 using (gx($1,$2)):(gy($1,$2)) notitle with lines 1, \
    " index 0 using (gx($1,$2)):(gy($1,$2)) notitle with lines 1
#pause -1
reset

# boundary lines for triangle
# index 0
100 0 0
0 100 0
0 0 100
100 0 0

# solid line
# index 1
90 10 0
53.5 28.5 18

# solid line spline extrapolation
# index 2
53.5 28.5 18
52.5 29 18.5
51.5 29 19.5
50.5 27.5 22

# solid line
# index 3
50.5 27.5 22
50.3 25 24.7
50.8 20 29.2
51.5 12.5 36

# solid line
# index 4
50 0 50
20 60 20

40 0 60
0 40 60

# dashed line
# index 5
80 0 20
80 20 0

70 0 30
70 30 0

60 0 40
60 40 0

50.3 25 24.7
33.4 33.2 33.4

# dashed line spline extrapolation
# index 6
50 50 0
50 40 10
52.5 29 18.5